Dans le cas présent, le TRX utilisé est un TS-590s qui possède deux connecteurs d’antennes que l’on peut commuter en envoyant une commande CAT de type « AN199; » pour Ant1 et « AN299; » pour Ant2.

L’idée est donc d’envoyer l’une ou l’autre de ces commandes alternativement, toutes les 2 minutes, juste avant que le cycle WSPR commence, suivant une table établie à l’avance, ce qui permet après dépouillement des données de savoir quelle antenne était en service.

L’enchainement du batch qui suit est très simple :

- Ouverture du port COM correspondant au TRX
- Pause d’une seconde (début de boucle)
- Si on est aux secondes 56, 57 ou 58, lecture de l’heure et extraction de la minute, sinon on retourne au début de la boucle d’attente
- En fonction de la minute, on commute soit Ant1, soit Ant2 pour le cycle qui va démarrer et on retourne au début de la boucle d’attente

La raison pour laquelle on envoie la cde CAT 3 fois de suite aux secondes 56, 57 et 58, est que le TS-590s est partagé entre plusieurs applications (avec des port COM virtuels), et que dans certains cas, il y a collision avec les envois CAT des autres applications (WSPR, et Win-Test). En envoyant la commande 3 fois de suite (méthode dite « bourrin »), on réduit les chances de collisions. Dans le cas d’une installation plus simple, un seul envoi serait suffisant.

Si on utilise un autre TRX qui possède 2 antennes commutables (TX et/ou RX), il suffit d’adapter la commande CAT à envoyer.

@ECHO OFF
REM Alternate TX Ant 1 and TX Ant 2, depending on the WSPR cycle
REM by sending a CAT command to the TS-590s 3 sec before
REM the WSPR cycle starts

REM (C) F6FVY - July 2019

REM xx00z, xx20z, xx40z : TX ant 1
REM xx02z, xx22z, xx42z : TX ant 2
REM xx04z, xx24z, xx44z : TX ant 1
REM xx06z, xx26z, xx46z : TX ant 2
REM xx08z, xx28z, xx48z : TX ant 1
REM xx10z, xx30z, xx50z : TX ant 2
REM xx12z, xx32z, xx52z : TX ant 1
REM xx14z, xx34z, xx54z : TX ant 2
REM xx16z, xx36z, xx56z : TX ant 1
REM xx18z, xx38z, xx58z : TX ant 2

REM COM port settings
mode COM9 BAUD=57600 PARITY=n DATA=8 STOP=1 >nul

:start
ECHO Waiting for time to switch TX antenna...
set ANT=

:loop
timeout /t 1 /nobreak > nul

REM Check if sec is 56, 57 or 58
REM So several CAT commands can be sent
REM in a row to prevent COM port congestion
REM or conflict with other apps

set SEC=%TIME:~6,2%
IF "%SEC%" LSS "56" GOTO loop
IF "%SEC%" GTR "58" GOTO loop

REM Check min mod 20 value

REM Note the "MIN=1%MIN% - 100"
REM trick to prevent "08" and "09"
REM to be considered as an
REM invalid octal ! WTF M$ !

set MIN=%TIME:~3,2%
set /a "MIN=1%MIN% - 100"
set /a "MOD20=%MIN% - ((%MIN%/20)*20)"

IF "%MOD20%" == "1" GOTO txant2
IF "%MOD20%" == "3" GOTO txant1
IF "%MOD20%" == "5" GOTO txant2
IF "%MOD20%" == "7" GOTO txant1
IF "%MOD20%" == "9" GOTO txant2
IF "%MOD20%" == "11" GOTO txant1
IF "%MOD20%" == "13" GOTO txant2
IF "%MOD20%" == "15" GOTO txant1
IF "%MOD20%" == "17" GOTO txant2
IF "%MOD20%" == "19" GOTO txant1
GOTO loop

REM To be safe, several commands are sent in a row
REM but display ant status once only

:txant2

set /p x="AN299;" <nul >\\.\COM9
IF "%ANT%" == "TX2" GOTO loop
ECHO TX ant 2 ON
set ANT=TX2
GOTO loop

:txant1

set /p x="AN199;" <nul >\\.\COM9
IF "%ANT%" == "TX1" GOTO loop
ECHO TX ant 1 ON
set ANT=TX1
GOTO loop

Il ne reste donc plus qu’à lancer le batch, et constater que l’antenne est bien commutée automatiquement juste avant le début de chaque cycle WSPR.

Après quelques heures de fonctionnement, il n’y a plus qu’à récupérer les données sur wsprnet.org, ou wspr.rocks et les dépouiller pour pouvoir comparer les deux antennes.

73

Laurent – F6FVY