Dans le cas présent, le TRX utilisé est un TS-590s qui possède deux connecteurs d’antennes que l’on peut commuter en envoyant une commande CAT de type « AN199; » pour Ant1 et « AN299; » pour Ant2.

L’idée est donc d’envoyer l’une ou l’autre de ces commandes alternativement, toutes les 2 minutes, juste avant que le cycle WSPR commence, suivant une table établie à l’avance, ce qui permet après dépouillement des données de savoir quelle antenne était en service.

L’enchainement du batch qui suit est très simple :

- Ouverture du port COM correspondant au TRX
- Pause d’une seconde (début de boucle)
- Si on est aux secondes 56, 57 ou 58, lecture de l’heure et extraction de la minute, sinon on retourne au début de la boucle d’attente
- En fonction de la minute, on commute soit Ant1, soit Ant2 pour le cycle qui va démarrer et on retourne au début de la boucle d’attente

La raison pour laquelle on envoie la cde CAT 3 fois de suite aux secondes 56, 57 et 58, est que le TS-590s est partagé entre plusieurs applications (avec des port COM virtuels), et que dans certains cas, il y a collision avec les envois CAT des autres applications (WSPR, et Win-Test). En envoyant la commande 3 fois de suite (méthode dite « bourrin »), on réduit les chances de collisions. Dans le cas d’une installation plus simple, un seul envoi serait suffisant.

Si on utilise un autre TRX qui possède 2 antennes commutables (TX et/ou RX), il suffit d’adapter la commande CAT à envoyer.

@ECHO OFF
REM Alternate TX Ant 1 and TX Ant 2, depending on the WSPR cycle
REM by sending a CAT command to the TS-590s 3 sec before
REM the WSPR cycle starts

REM (C) F6FVY - July 2019

REM xx00z, xx20z, xx40z : TX ant 1
REM xx02z, xx22z, xx42z : TX ant 2
REM xx04z, xx24z, xx44z : TX ant 1
REM xx06z, xx26z, xx46z : TX ant 2
REM xx08z, xx28z, xx48z : TX ant 1
REM xx10z, xx30z, xx50z : TX ant 2
REM xx12z, xx32z, xx52z : TX ant 1
REM xx14z, xx34z, xx54z : TX ant 2
REM xx16z, xx36z, xx56z : TX ant 1
REM xx18z, xx38z, xx58z : TX ant 2

REM COM port settings
mode COM9 BAUD=57600 PARITY=n DATA=8 STOP=1 >nul

:start
ECHO Waiting for time to switch TX antenna...
set ANT=

:loop
timeout /t 1 /nobreak > nul

REM Check if sec is 56, 57 or 58
REM So several CAT commands can be sent
REM in a row to prevent COM port congestion
REM or conflict with other apps

set SEC=%TIME:~6,2%
IF "%SEC%" LSS "56" GOTO loop
IF "%SEC%" GTR "58" GOTO loop

REM Check min mod 20 value

REM Note the "MIN=1%MIN% - 100"
REM trick to prevent "08" and "09"
REM to be considered as an
REM invalid octal ! WTF M$ !

set MIN=%TIME:~3,2%
set /a "MIN=1%MIN% - 100"
set /a "MOD20=%MIN% - ((%MIN%/20)*20)"

IF "%MOD20%" == "1" GOTO txant2
IF "%MOD20%" == "3" GOTO txant1
IF "%MOD20%" == "5" GOTO txant2
IF "%MOD20%" == "7" GOTO txant1
IF "%MOD20%" == "9" GOTO txant2
IF "%MOD20%" == "11" GOTO txant1
IF "%MOD20%" == "13" GOTO txant2
IF "%MOD20%" == "15" GOTO txant1
IF "%MOD20%" == "17" GOTO txant2
IF "%MOD20%" == "19" GOTO txant1
GOTO loop

REM To be safe, several commands are sent in a row
REM but display ant status once only

:txant2

set /p x="AN299;" <nul >\\.\COM9
IF "%ANT%" == "TX2" GOTO loop
ECHO TX ant 2 ON
set ANT=TX2
GOTO loop

:txant1

set /p x="AN199;" <nul >\\.\COM9
IF "%ANT%" == "TX1" GOTO loop
ECHO TX ant 1 ON
set ANT=TX1
GOTO loop

Il ne reste donc plus qu’à lancer le batch, et constater que l’antenne est bien commutée automatiquement juste avant le début de chaque cycle WSPR.

Après quelques heures de fonctionnement, il n’y a plus qu’à récupérer les données sur wsprnet.org, ou wspr.rocks et les dépouiller pour pouvoir comparer les deux antennes.

73

Laurent – F6FVY

Depuis quelques temps, et suite à l’excellent compte-rendu de F4DLM relatant ses essais en WSPR pendant sa participation à l’expédition TO7CC sur l’Ile de la Réunion, je m’intéresse à ce mode numérique utilisé à des fins d’étude de propagation, fort peu gourmand en énergie et en bande passante (6 Hz). Néanmoins, une condition indispensable à son exploitation est d’avoir une machine qui génère l’émission (et/ou qui décode la réception) qui soit parfaitement à l’heure. Sans entrer dans les détails techniques du WSPR (qui feront peut-être l’objet d’un autre article), une précision d’une ou deux secondes maximum est requise.

Force a été de constater que mon PC était loin du compte, et les paramètres par défaut que j’utilisais nécessitaient régulièrement une synchro forcée pour être dans les clous. La « synchro Internet » (Propriétés de Date et Heure / Temps internet / Synchro auto) ne suffisait pas à maintenir une précision suffisante. J’avais parfois plusieurs dizaines de secondes de décalage. Même en diminuant la période de mise à jour à 6h (par le truchement de la modification d’une clé de registre), ça ne suffisait pas encore. Il est certes est fort probable que l’oscillateur dont est équipé mon PC soit particulièrement mauvais (dérive avec le temps et la température), mais il était indispensable de le « discipliner » !

Le service W32Time qui, comme son nom l’indique, gère l’heure dans Windows n’est en fait qu’un ersatz de NTP, protocole connu et reconnu pour assurer cette fonction. Les périodes de mise à jour de W32Time sont longues et non auto-adaptatives, entre autres inconvénients. Microsoft reconnait lui-même qu’avoir une ou deux secondes de précision n’est pas vraiment possible avec W32Time. J’ai donc décidé de désactiver le service W32Time, et de le remplacer par un véritable service NTP.

Installation

Le package d’installation de NTP pour Windows se trouve ici. On trouve également sur cette page un utilitaire graphique permettant un paramétrage plus fin, et un suivi des données (notamment le décalage par rapport à l’heure « vraie ») par le truchement de fichiers de statistiques générés à la demande.

L’installation ne nécessite que de suivre les écrans et d’utiliser les choix par défaut (sauf si vous savez ce que vous faites). A noter néanmoins qu’il est conseillé de choisir le pool de serveurs le plus proche de chez vous (si vous êtes en France Métropolitaine, ce sera fr.pool.ntp.org). De plus, avant même de lancer l’installation, faites une synchro forcée de votre horloge. Cela facilitera le travail du nouveau service NTP à son démarrage. Après l’installation et son lancement automatique, vérifiez que W32Time est bien désactivé (Propriétés de Date et Heure / Temps internet / Synchro auto doit être décochée). Une fois tout en place, il ne reste plus qu’à attendre quelques minutes (ou quelques heures…) pour constater l’efficacité de ce nouveau service.

Fonctionnement

Le plus simple est d’installer le moniteur graphique (cf lien plus haut), de le lancer, et aller dans l’onglet NTP Status.

Une liste de serveurs doit être affichée. Celui en vert est celui sur lequel se base à cet instant le service pour corriger votre horloge. Les autres en jaune sont également candidats pour une synchro si besoin. Si certains sont en rouge, ils sont pour l’instant écartés, soit parce qu’ils sont trop éloignés statistiquement, soit que la liaison avec le serveur est trop instable. Les deux paramètres les plus intéressants sont l’offset (décalage entre l’heure vraie et votre horloge, exprimé en ms), et le jitter (dispersion). Le poll indique la période (en secondes) à laquelle le service refait un tour des serveurs et ajuste l’oscillateur de votre horloge. Ce qu’il faut bien comprendre, c’est que le service ne met pas brutalement et simplement votre horloge à jour, mais l’ajuste par petites touches régulières, de plus en plus fines. Et au fur et à mesure du temps, la période de mise à jour s’adapte en fonction des écarts. Voici par exemple ci-dessous l’évolution du décalage entre l’heure vraie et celle de mon horloge (tracé rouge) sur une dizaine d’heures.

On constate des amplitudes d’évolutions de plus en plus petites au fur et à mesure du temps. Les rebonds sont causés par une augmentation de la période de polling, qui diminue de nouveau après quelques minutes car l’écart augmente trop. Comme indiqué en introduction, la stabilité de l’oscillateur de ma machine est probablement assez mauvaise, et les évolutions de la température du boitier en fonction de l’heure de la journée et/ou de l’utilisation du CPU ne doivent pas aider. Cela dit, même obtenir une horloge précise à +/- 100 msec me suffit amplement !

Bien entendu, l’utilisation d’un tel service NTP est assujetti à la disponibilité d’une connexion Internet. Pour une solution nomade ou autonome, on peut faire appel à des horloges radio-pilotées (type DCF77), ou à des modules GPS qui sont devenus désormais très abordables. Mais c’est un autre sujet !

Références

- Description détaillée de l’installation et l’utilisation de NTP sur Windows (anglais) : http://www.satsignal.eu/ntp/setup.html
- L’heure précise avec un navigateur : http://time.gov
- La page wikipedia française sur NTP : https://fr.wikipedia.org/wiki/Network_Time_Protocol
- Comment fonctionne NTP (anglais) : http://www.ntp.org/ntpfaq/NTP-s-algo.htm#Q-CLOCK-DISCIPLINE